USGS Coastal & Marine Geology
Wong, F.L., Hamer, M.R., Hampton, M.A., and Torresan, M.E., 1996, Bottom Characteristics of an Ocean Disposal Site off Honolulu, Hawaii: Time-based Navigational Trackline Data Managed by Routes and Events: Redlands, California, Environmental Systems Research Institute, 1996 ESRI Users Conference Proceedings (cdrom), approx. 15 p.

Table 5. Exerpts of Arc Macro Language (AML) programs listing essential commands to compute geodata sets described in this report.

mkroute.aml create route system from 1-min navigation log
mkpointeve.aml create INFO point event table
mklineeve.aml create INFO line event table for tracklines
plotrt.aml plot events along routes
event2arc.aml convert line events to arc coverage
plottrk.aml plot arcs
morphpt.aml convert arcs to points and plot them


/* mkroute.aml: create (1) route system and (2) point event table from one-minute navigation fixes

/* Variables
/* rtdat GENERATE>ROUTE input file
/* rtll27 route in geographic coordinates
/* track name of route system
/* k194navrt name of route coverage
/* 
/* input file 'rtdat'
/* 1
/* 1300009 -157.88913 21.31902
/* 1300010 -157.88914 21.31904
/* 1300011 -157.88925 21.31889
/* 1300012 -157.88928 21.31881
/* 1300013 -157.88929 21.31882
/* ...
/* END
/* END
/*
/* Build single route (track-id = 1) in geographic coordinates
/* and convert to projection of study %proj%
/*
GENERATE rtll27
INPUT rtdat
ROUTES track
Q
PROJECT COVER rtll27 k194navrt %proj%





/* mkpointeve.aml: generate point event table from one-minute navigation fixes

/* variables
&s navlog rtdat2 /* file of trackno, time, long, lat (similar to 'rtdat')
&s tbl k194pt.eve /* point event table
/* 
TABLES
DEFINE %tbl%
track#,4,4,i /* = 1, route number from k194navrt
time,7,7,c
longitude,4,10,f,5
latitude,4,9,f,5
~
ADD FROM %navlog%
/*
/* redefine time to day, hr, min for queries
REDEFINE
5,timei,7,7,c
5,day,3,3,i
8,hr,2,2,i
10,min,2,2,i
~
/*
/* point event table: track# is the event key, time is the measure
/*
/* track# time longitude latitude day hr min
/* ...
/* 1 1300009 -157.88913 21.31902 130 0 9
/* 1 1300010 -157.88914 21.31904 130 0 10
/* 1 1300011 -157.88925 21.31889 130 0 11
/* 1 1300012 -157.88928 21.31881 130 0 12
/* 1 1300013 -157.88929 21.31882 130 0 13
/* ...




/* mklineeve.aml: create INFO line event table for tracklines

/* variables
&s cov k194navrt /* route coverge
&s startend k194equip /* equipment deployment; see Table 2 for excerpt
&s tbl k194trkno.eve /* line event table
/*
TABLES
DEFINE %tbl%
track#,4,4,i /* = 1, route number from k194navrt
start,4,12,f,0
end,4,12,f,0
lineno,4,4,c
comment,20,15,c
~
/*
ADD FROM %startend%
/*
/* Line event table k194trkno.eve
/*
/* Record track# start end lineno comment
/* ...
/* 9 1 1310943 1311150 9 Geophysics
/* 10 1 1311226 1311428 10 Geophysics
/* 11 1 1311450 1311643 11 Geophysics
/* 12 1 1311749 1312339 12A Camera 3
/* 13 1 1320000 1320220 6B Camera 4
/* 14 1 1320312 1320533 13 Geophysics
/* 15 1 1320555 1320800 14 Geophysics
/* ...




/* plotrt.aml: plot events along routes

/* variables
&s cov k194navrt /* route coverage
&s route track /* route system
&s evsrc1 pteve /* eventsource or relate for point events
&s tblpt k194pt.eve /* point event table
&s evsrc2 trkeve /* eventsource for line events
&s tblln k194trkno.eve /* linear event table
/*
ARCPLOT
/*
MAPEXTENT %cov%
/*
/* establish relate to event table; usage:
/* EVENTSOURCE ADD 
/* {database} {relate_type} {route_key_item} {event_key_item}
/* {measure_item} {measure_item
/*
EVENTSOURCE ADD LINEAR %evsrc2% %tblln% INFO ordered track# track# start end
/*
/* camera ON segments
EVENTLINES %cov% %route% %evsrc2% 
/*
/* camera line numbers
EVENTLINETEXT %cov% %route% %evsrc2% lineno
/*
/* 10-minute marks
EVENTSOURCE ADD POINT %evsrc1% %tblpt% INFO ordered track# track# timei
RESELECT %tblpt% INFO min in {0,10,20,30,40,50}
EVENTMARKERS %cov% %route% %evsrc1%




/* event2arc.aml: convert line events to arc coverage

/* Variables
&s cov k194navrt /* route coverage
&s route track /* route name
&s evsrc trkeve /* eventsource or relate
&s tbl %dir%/k194trkno.eve /* linear event table
&s linecov k194camtrk /* coverage of camera survey lines
/*
/* establish relate to event table
EVENTSOURCE ADD LINEAR %evsrc% %tbl% info ordered track# track# start end
/*
/* convert line events to arc coverage; usage:
/* EVENTARC 
/* {offset_item | constant} {offset_lookup} {selection_file}
/*
EVENTARC %cov% %route% %evsrc% %linecov%




/* plottrk.aml: plot camera lines for K194 with line numbers

/* Variables
&s cov k194camtrk /* camera line coverage
&s item lineno
/* 
ARCPLOT
/*
MAPEXTENT %cov%
/*
/* camera lines
ARCS %cov%
/*
/* camera line numbers at both ends of line
ARCENDTEXT %cov% camline # POINT1 BOTH




/* morphpt.aml: create and plot point coverage of photo observations

/* Create INFO line event table 'morphol.eve' using process in
/* MKLINEEVE.AML above with data similar to excerpt in Table 3.
/* 
/* Convert line events to arc coverage 'morphol' as in
/* EVENT2ARC.AML above.
/* 
/* Convert arc coverage 'morphol' to point coverage 'morphpt'
/*
ARCPOINT morphol morphpt LINE morphol-id
/*
/* assign attributes to the points via a relate 'morphola'
/* to the arc attribute table keyed to the arc-id.
/*
/* RELATION = MORPHOLA
/* TABLE-ID = morphol.aat
/* DATABASE = info
/* ITEM = MORPHOL-ID
/* COLUMN = morphol-id
/* TYPE = ORDERED
/* ...
/*
/* to plot type of bottom morphology point symbols via a lookup table
/*
ARCPLOT
/*
POINTMARKERS morphpt morphola//morphtype morphtype.lut
/*
/* for current directions
/*
POINTMARKERS morphpt morphola//facedir dir.lut


Top of page Beginning of article

Reports Honolulu Home Search

URL: http://walrus.wr.usgs.gov/reports/wong96/p1148.html
Maintainer: Florence L. Wong
Last modified: 01 Oct 97.

U.S. Department of the Interior, U.S. Geological Survey, Western Coastal and Marine Geology